Requires: SmartSpice & Smartview

Minimum Versions: SmartSpice 3.16.12.REAC functionality here !

• No example available at the moment.

Input Files

6tr1cap_runtime.in

6TR1cap

.OPTIONS DCGMIN=1E-18
.OPTIONS GMIN=1E-18
.options post=2 probe rawpts=800 nomod nodeck ingold=2 acct vzero=2 $ node list  epic=2
.width out =200

.temp 27

.lib '6tr1cap_runtime.lib' TT

**************6TR1cap netlist*****************
XP1  11 GATE  12  ptft	 L=20e-6 W=5e-6
XP2     12       GW[1]     GATE 		 CONV        L=8e-6 W=4e-6 
XP3     GATE 	   GI[1]     VINT        CONV        L=8e-6 W=4e-6 
XP4 		11  	   GW[1]     DATA      CONV        L=4e-6 W=4e-6
XP5 		ELVDD 	 EM[1]     11        CONV        L=4e-6 W=4e-6 
XP6 		12 	 	   EM[1]     15        CONV      L=4e-6 W=4e-6
CST 		ELVDD 	 GATE 	   0.6p         
D_G 		15    ELVSS 	 GEL_Diode        w=42u l='84u*0.1662'

***timing***
V_gi	  gi[1]	ground	pulse	(vgh	   vgl	    10u    1u  1u  20u    1m)
V_GW	  gw[1]	ground	pulse	(vgh	   vgl	    40u    1u  1u  20u    1m)
V_EM	  em[1]	ground	pulse	(vgl	   vgh	    5u     3u  3u  60u    1m)
V_DATA  DATA  ground	pulse	(DATA_B	 DATA_W	  999u   1u  1u  2m     3m)

***DC power****
V_ELVSS  ELVSS         GROUND DC  -6.5
V_ELVDD  ELVDD         GROUND DC  3
V_VINT   VINT          GROUND DC  -2


.probe v(gate,12) @m.xp1.m1[vto]

.PARAM vgh=5.2 vgl=-7
.PARAM DATA_B=4.2  
.PARAM DATA_W=2 

.measure 	tran	 I_Black	avg	i(D_G)	from=	{100u}	to=	{900u}
.measure 	tran	 I_White1	avg	i(D_G)	from=	{1100u}	to=	{1900u}
.measure 	tran	 I_White2	avg	i(D_G)	from=	{2100u}	to=	{2900u}

.TRAN  1n 3m 
  
.END