Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 3.17.26.C

The
input deck uses a BSIM3 model in a single SRAM cell to show disruption due to a particle hit.

Operation:
The deck runs automatically after sourcing.

A plot automatically displays showing:

• v(up) – Upset pulse at 10ns
• v(a) – Disruption on a positive signal level
• v(b) – Disrumption on a low level signal.

Graphics

Input Files

sram8_MN1.in

* SRAM: PULSE DURATION 0.01n

.option itl1=500 gmin=1e-15 dcgmin=1e-15 itl4=10
.option nomod nodeck numdgt=8 measraw=0 probe
*.option trtol=3.5 $lvltime=2

vdd dd 0 dc 2 pulse 0 2 0 1n 1 1 1
vss ss 0 dc 0

.ic v(a)=2 v(b)=0

* Impact on a node
mp1  a b  dd  dd  P1 w=3.6u l=1.2u
mn1  a b  ss  ss  N1 w=1.8u l=1.2u
mp2  b a  dd  dd  P1 w=3.6u l=1.2u
mn2  b a  ss  ss  N1 w=1.8u l=1.2u

.tran 0.2n 20n 0 1n 
.rad SEE Lf=5e-6
+ device=mn1 annotate=1
+ source=vup ; user-defined expr.
+ node=ndp iseu=0.8e-3  ; => MOS switchs

*.probe all
*.probe @mn1[qdep] @mn1[iseu]
*.probe @mn1[vdsat] @mn1[vth] @mn1[vgs] @mn1[vds] 
.probe v(up) v(a) v(b)

Vup up 0 exp 0 1 10n 5p 10.001n 100p
Rup up 0 1 

.include ./model.nmos
.include ./model.pmos

.measure tran qdeptot integral @mn1[iseu] from=0 to=20n
.measure tran tc_vg cross @mn1[vth] @mn1[vgs]
.measure tran t2_vd cross @mn1[vdsat] @mn1[vds]
.measure tran tva8n point v(a) arg0=8n
.measure tran tva17nn point v(a) arg0=17n
.measure tran tvb8n point v(b) arg0=8n
.measure tran tvb17nn point v(b) arg0=17n 

.control 
 run batchprint
.endc

.iplot v(up) v(a) v(b)

.end

023_seu_sim

[an error occurred while processing this directive]