Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 3.16.12.R

This input deck shows you how to produce a single element Frequency Modulated Source .

Input Files

mod1.in

Parametric analysis
***** Circuit description
vcc vss 0  DC vccDC
vin inp 0  PULSE(0 3 0 trtf trtf  10ns 40ns)
m1 2  inp  vss  vss  pm  w=wp   l=1.6u
m2 2  inp  0    0    nm  w=30u  l=2.0u
cout  2  0  50ff 
.MODEL  pm  PMOS ( level=3 tox=.02e-6
+ phi=0.576 gamma=0 vto=0 alpha=0 kappa=0)
.model  nm  NMOS ( level=3 tox=.02e-6
+ phi=0.576 gamma=0 vto=0 alpha=0 kappa=0)
***** Analysis statement
.TRAN 0.1ns 25ns
***** Measure statements
.MEASURE TRAN delrise DELAY v(inp) RISE=1 VAL=1.5
+      TARG=v(2) FALL=1 VAL='0.5*vccDC' 
.MEASURE TRAN maxv2 MAX  v(2) 
.MEASURE TRAN delfall DELAY v(inp) FALL=1 VAL=1.5
+      TARG=v(2) RISE=1 VAL='0.5*maxv2' 
***** Parameter labels
.PARAM vccDC= 5V wp=4.9u  trtf=1ns
***** Parametric analysis  specification
.MODIF proff  prtbl m2(w)=32.6u  LOOP=6 vccDC+=(4.5)0.1v    
+MODIF proff  prtbl     TEMP=75  LOOP=6 vccDC+=(4.5)0.1v    
.options nomod
.END

opDC.in

Invertor  DC Optimization  
***** Circuit
vcc 0   vss    dc -5v
vin inp 0      dc 1.55v
m1 2  inp  vss  vss  pm  w=wp   l=lp
m2 2  inp  0    0    nm  w=20u  l=2.0u
***** Models
.MODEL  pm  PMOS ( level=3 tox=.02e-6
+ phi=0.576 gamma=0 vto=0 alpha=0 kappa=0)
.model  nm  NMOS ( level=3 tox=.02e-6
+ phi=0.576 gamma=0 vto=0 alpha=0 kappa=0)
***** Analysis statement
.DC vin 0 5  0.1 
***** Measure statements
.MEASURE DC maxcur MAX    i(vcc) 
.MEASURE DC trip   CROSS  v(2)  v(inp)
***** Parameter labels
.PARAM wp=10u lp=1.6u
***** Optimization specification
.MODIF 
+ OPTIMIZE wp=OPT(2.0e-7 30e-6 10e-6) m2(w)=OPT(5u 100u 20u )
+ TARGETS  trip=1.55   maxcur=0.0019 
+ OPTIONS  MEASOFF=0 AVG=0.001 
***** Interactive plot
.IPLOT v(inp) v(2)
.OPTIONS iplot_one nomod
.END