Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 3.17.26.C

This
input deck shows how to change current temperature during a transient analysis
using .RTTEMP statement with PWL function. PWL can contain expressions.

This
input deck shows how to change current temperature during a transient analysis
using .RTTEMP statement with PWL function. PWL can contain expressions.
shows how to change current temperature during a transient analysis
using .RTTEMP statement. .RTTEMP statement saves ‘temp’ vector into a raw file.

Graphics

Input Files

rttemp_const_val.in

.rttemp  testing 
**************************
VIN  1 0  DC 0  SIN(0 0.1 5MEG)  AC 1
VCC  8 0  DC 10
VEE  9 0  DC -12
RS1  1 2  1K
RS2  5 0  1K
RC1  3 8  10K
RC2  4 8  10K
RBIAS  7 8  20K
CLOAD  3 4  5PF
Q1  3 2 6  QNL
Q2  4 5 6  QNL
Q3  6 7 9  QNL
Q4  7 7 9  QNL
.MODEL QNL NPN(BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF VA=50)
.TRAN 5NS   10u   

.OPTIONS nomod nodeck  method=gear
.probe i(vee)

.rttemp 60  3u   90  6u

.measure tran  min_cur_VEE_at27temp   min  i(vee)  from=1u to=2u
.measure tran  min_cur_VEE_at60temp   min  i(vee)  from=3u to=4u
.measure tran  min_cur_VEE_at90temp   min  i(vee)  from=6u to=7u

.measure tran  max_cur_VEE_at27temp   max  i(vee)  from=1u to=2u
.measure tran  max_cur_VEE_at60temp   max  i(vee)  from=3u to=4u
.measure tran  max_cur_VEE_at90temp   max  i(vee)  from=6u to=7u

.measure tran  avg_cur_VEE_at27temp   avg  i(vee)  from=1u to=2u
.measure tran  avg_cur_VEE_at60temp   avg  i(vee)  from=3u to=4u
.measure tran  avg_cur_VEE_at90temp   avg  i(vee)  from=6u to=7u

.measure tran  temp_avg27temp   avg  temp    from=1u to=2u
.measure tran  temp_avg60temp   avg  temp    from=3u to=4u
.measure tran  temp_avg90temp   avg  temp    from=6u to=7u

.END

rttemp_pwl_param.in

.rttemp example with expressions in PWL
*********************************************
VIN  1 0  DC 0  SIN(0 0.1 5MEG)  AC 1
VCC  8 0  DC 10
VEE  9 0  DC -12
RS1  1 2  1K
RS2  5 0  1K
RC1  3 8  10K
RC2  4 8  10K
RBIAS  7 8  20K
CLOAD  3 4  5PF
Q1  3 2 6  QNL
Q2  4 5 6  QNL
Q3  6 7 9  QNL
Q4  7 7 9  QNL
.MODEL QNL NPN(BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
+   VA=50)
.TRAN 5NS   1u   

.OPTIONS nomod nodeck  method=gear
.probe i(vee)

.PARAM t1=27 t2=50 t3=120 dt=50n time1=200n time2=600n time3=900n time4=1u 
.RTTEMP PWL (0 t1   "time1-dt" t1   time1 t2   "time2-dt" t2   time2 t3  time3 t3)

.measure tran  cur_vee_minT1_27    min  i(vee)  from=0n to=150n
.measure tran  cur_vee_minT2_50    min  i(vee)  from=200n to=550n
.measure tran  cur_vee_minT3_120   min  i(vee)  from=600n to=850n

.measure tran  temp_avgT1_27    avg  temp  from=0n to=50n
.measure tran  temp_avgT2_50    avg  temp  from=200n to=250n
.measure tran  temp_avgT3_120   avg  temp  from=600n to=650n

.END