Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 4.6.5.R

The input deck uses both .NOISE and .MEASURE analysis to show influences on AC noise levels.

Input Files

rubberband_example_18.in

***
* The following deck checks measurement for the
* NOISE analysis. It must be performed for 
* NOISES plot only.
*
* Created by IZ Feb 03, 1994
*
***

.noise v(out3a,out4a) vin dec 10 1 10G 1

.meas noise mx max onoise_s.q.x1.q2.1overf
.meas       mn min onoise_s.q.x1.q2.1overf
.meas       wv wave onoise_s.q.x1.q2.1overf 
+                   val0=mn val1=mx fall=1

vref 20 0 2.5
vin  10 0 dc 2.5 ac 10m pulse 2 3 0 50ps 50ps 5ns 10 100
c3a out3a 0 1p
c4a out4a 0 1p
c3b out3b 0 1p
c4b out4b 0 1p

x1 10 20 out3a out4a 0 ampl1
x2 10 20 out3b out4b 0 ampl2

.subckt ampl1 1 2 3 4 gnd
q1 3 1 5 gnd bjtmod m=10
q2 4 2 5 gnd bjtmod m=10
r1 6 3  500
r2 6 4  500
v1 6 gnd dc 5
i1 5 gnd dc 4m
.ends

.subckt ampl2 1 2 3 4 gnd
q10 3 1 5 gnd bjtmod
q11 3 1 5 gnd bjtmod
q12 3 1 5 gnd bjtmod
q13 3 1 5 gnd bjtmod
q14 3 1 5 gnd bjtmod
q15 3 1 5 gnd bjtmod
q16 3 1 5 gnd bjtmod
q17 3 1 5 gnd bjtmod
q18 3 1 5 gnd bjtmod
q19 3 1 5 gnd bjtmod
q20 4 2 5 gnd bjtmod
q21 4 2 5 gnd bjtmod
q22 4 2 5 gnd bjtmod
q23 4 2 5 gnd bjtmod
q24 4 2 5 gnd bjtmod
q25 4 2 5 gnd bjtmod
q26 4 2 5 gnd bjtmod
q27 4 2 5 gnd bjtmod
q28 4 2 5 gnd bjtmod
q29 4 2 5 gnd bjtmod
r1 6 3  500
r2 6 4  500
v1 6 gnd dc 5
i1 5 gnd dc 4m
.ends

.model bjtmod npn 
+ is=1.62e-17		bf=233.2		nf=1.0
+ vaf=51.2		ikf=3.53e-2		
+ ise=6.89e-16		ne=1.735		
+ var=4.0		br=15.1			nr=1.00
+ ikr=1.82e-3		isc=5.31e-15		nc=1.62
+ rb=99.7		rbm=22.3		
+ re=12.3		rc=27.0	
+ cje=4.04e-14		vje=0.83		mje=0.356
+ cjc=2.38e-14		vjc=0.6			mjc=0.167
+ cjs=2.44e-14		vjs=0.6			mjs=0.124
+ xcjc=0.3		fc=0.97		
+ tf=8.5p		xtf=6.0			vtf=1.0
+ itf=1.96e-2		ptf=12			tr=1.3n
+ eg=1.15		xti=3.0			xtb=0.7
+ trb1=2.8e-3		trb2=8.0e-6
+ trm1=2.8e-3		trm2=8.0e-6
+ tre1=6.0e-4		tre2=1.2e-6
+ trc1=1.2e-3		trc2=2.4e-6		kf=1.e-12

.end