Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 4.6.5.R

This Transient Noise example input deck with .TRAN NOISE and .MEASURE shows how to get a feel of noise influences on the transient response of your circuit by rubberbanding cc[cap], rb[res] and rc[res].

Input Files

rubberband_example_11.in

* HBT Tran NOISE Analysis Test                                                           
* Rubberband parameters:
* cc[cap] 
* rb[res] 
* rc[res]

.options nomod   

Vc  1  0  5.0
Vin in 0  PULSE(0 3 0 5ns 5ns vin_control 75ns)
Rb  in bas  1k
Rc  col  1  1k
Cc  col  0  1f

Q1  col  bas  0  0  P23L  479e-3 

.param vin_control=30ns

.tran 1ps 80ns NOISE
+ Freq=50 Freqh=100000000 

.probe V(in) V(col)
.MEASURE TRAN CorMaxCol MAX k(col)
.MEASURE TRAN CorMinCol MIN k(col)
.MEASURE TRAN CorMaxIn MAX k(in)
.MEASURE TRAN CorMinIn MIN k(in)

* model card (proprietary, CJS modified)

*********************************************************************************************************
*****MODEL  P23L:UCSD     WD180:BJT *****
*********************************************************************************************************

.MODEL P23L NPN level=20
+ SELFT = 1.000
+ TNOM = 27.00 IS = 2.08742E-24
+ NF = 1.039 NR = 1.070  ISA = 20.11m  NA = 3.406  ISB = 30.55f
+ NB = 1.754  VAF = 21.78  VAR = 2.999  IK = 26.26m  BF = 118.8
+ BR = 47.91m ISE = 1.04441E-20 NE = 24.34 ISEX = 407.7f  NEX = 3.370
+ ISC = 70.19a NC = 2.786  ISCX = 1.000p  NCX = 2.686  FA = 900.0m
+ BVC = 1.000K  NBC = 8.000 ICS = 344.2p  NCS = 14.08  
* + RE = 2.558   
+ RCX = 6.304
+ REX = 1.000  RBX = 173.2m RBI = 15.46    RCI = 10.00
+ CJE = 22.15f VJE = 915.4m  MJE = 55.38m  CEMIN = 20.43f FCE = 589.6m
+ CJC = 17.74f VJC = 1.077  MJC = 350.4m  CCMIN = 16.21f FC = 800.0m
+ CJCX = 11.82f VJCX = 1.077  MJCX = 350.4m  CXMIN = 10.81f  XCJC = 800.0m
+ CJS = 2f  VJS = 2.000  MJS = 1.000m  TFB = 24.67f  TBEXS = 0
+ TBCXS = 0.000  TFC0 = 669.1f  ICRIT0 = 908.1  ITC = 14.34m ITC2 = 13.70m
+ VTC = 662.7m  TKRK = 1.000a  VKRK = 1.000K  IKRK = 1.000K  TR = 0
+ TRX = 0  FEX = 18.86m  RTH = 1.322K  CTH = 100.0p  KFN = 1E-12
+ AFN = 1.000  BFN = 1.000  XTI = 5.000  XTB =-2.510 TNE = 0
+ TNC = 0  TNEX = 0.000  EG = 1.393  EAA = 0  EAB = 0
+ EAC = 0  EAE = 0  EAX = 0  XRE = 0  XREX = 0
+ XRB = 0  XRC = 0  TVJE = 0  TVJCX = 0  TVJC = 0
+ TVJS = 0  XTITC = 0  XTITC2 = 0  XTTF = 0 XTTKRK = 0
+ XTVKRK = 0  XTIKRK = 0  XRT = 0 DTMAX = 1.000K

.END