Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 3.16.12.R

The example shows an ability to cut-off simulation time using AUTOSTOP option. The simulation is stopped at the moment when all the measure are calculated. New development gives an opportinity to calculate runtime evaluation in .MEASURE statements during the simulation. The simulation in the following example will stop at 375ns instead of 500ns as specified in .TRAN statement

The input deck is a SPICE file containing the test bench of SPICE statements, options, and models required to run ths simulation.

Input Files

ex1_autostop.in

* AUTOSTOP TEST

**************************************
* Netlist
VIN  1 0  DC 0  SIN(0 0.1 5MEG)  AC 1
VCC  8 0  DC 10
VEE  9 0  DC -12
RS1  1 2  1K
RS2  5 0  1K
RC1  3 8  10K
RC2  4 8  10K
RBIAS  7 8  20K
CLOAD  3 4  5PF
Q1  3 2 6  QNL
Q2  4 5 6  QNL
Q3  6 7 9  QNL
Q4  7 7 9  QNL
**************************************

**************************************
* Model definition
.MODEL QNL NPN(BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
+   VA=50)
**************************************

* Analysis statement
.TRAN 5NS 500NS

* AUTOSTOP option allows to decrease simulation time significantly
.OPTIONS NOMOD NODECK AUTOSTOP
.SAVE v(3)


**************************************
* Measurement section
*   New development gives an opportinity to calculate runtime evaluation in .MEASURE 
*   statements during the simulation
.MEASURE TRAN voltage_3 MAX v(3) FROM='100n' TO='300n'
.MEASURE TRAN time_4 FIND time WHEN V(3)='voltage_3*0.95' CROSS=1  FROM='300n'
**************************************

.END