Requires: SmartSpice & Smartview

Minimum Versions: SMARTSPICE 3.16.12.R

• Some forms of .MESURE statement

Here a simple test circuit of a Bipolar “long-tail” pair is used with a sine wave input to generate waveforms under transient analysis. The transient vectors are then referenced by a .MEASURE statement to extract key values.
This indicates some of the power of thw .Measure statement that can be applied to a number of anlysis like AC, DC, FFT etc. as well as TRAn analysis, more details are given in a chapter of the SmartSpice users manual.

Graphics

Input Files

ex1_multi_meas.in

DEMO EXAMPLE 1: INPUT FILE
*******************************************************************************
* Do multiple .MEASURE statements on whole or part of vector output waveforms
*  and store results in output RAW file
*****************************************************************************cs

VIN  1 0  DC 0  SIN(0 0.1 5.1MEG)  AC 1
VCC  8 0  DC 10
VEE  9 0  DC -12
RS1  1 2  1K
RS2  5 0  1K
RC1  3 8  10K
RC2  4 8  10K
RBIAS  7 8  20K
CLOAD  3 4  5PF
Q1  3 2 6  QNL
Q2  4 5 6  QNL
Q3  6 7 9  QNL
Q4  7 7 9  QNL
.MODEL QNL NPN(BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF VA=50)
*
.OPTION savemeasures

.DC VIN -0.25 0.25 0.025
.OP current 20ns
.TRAN 5NS 2.0u
*  
.measure  DC max_ic_q1 MAX ic(Q1)
.measure tran max_in MAX v(VIN)
.measure tran max_isup1 max i(VEE)
.measure tran max_isup2 max i(VCC)
.measure tran max_iload max i(cload)
.meas tran new_val  PARAM ='max_isup1 - max_isup2' 

********************* new meas setup
.param var_t0 = 50n
.param var_t15 = 1550n

.meas tran pt_r1_0 find I(RC1) at=var_t0
.meas tran pt_r1_15 find I(RC1) at=var_t15
.meas tran slope param="(pt_r1_15 - pt_r1_0) / (var_t15 - var_t0)"
.meas tran y0 param="pt_r1_0 - slope*var_t0"

*************************************

.save all(v) all(i)

.OPTIONS ACCT RELTOL=0.001 NOMOD
.END

ex1_multi_meas.measure.raw0

Title:      DEMO EXAMPLE 1: INPUT FILE
Input deck file name: U:\smartspice_web\analysis\014_measure\ex1_multi_meas.in
Date: Thu Nov 14 17:37:34 2019
Plotname: Measure Plot
Temperature: 0
Sweepvar: max_ic_q1
Sweepmode: 0
Flags: real padded
No. Variables: 10
No. Points: 1         
Source: SmartSpice,Platform:0
Version: 4.38.1.R
Variables:	0	max_ic_q1	notype
	1	max_in	notype
	2	max_isup1	notype
	3	max_isup2	notype
	4	max_iload	notype
	5	new_val	notype
	6	pt_r1_0	notype
	7	pt_r1_15	notype
	8	slope	notype
	9	y0	notype
Values:
 0	1.063523287715098e-003
	1.000000000000000e-001
	2.322313224847328e-003
	-2.292432322858670e-003
	2.558617001457824e-004
	4.614745547705998e-003
	-6.872456899788083e-004
	-5.578289290819505e-004
	8.627784059790520e+001
	-6.915595820087036e-004

014_measure

[an error occurred while processing this directive]