* .acheck example

*V 1 0 SIN(0 1 1M)

V1 v1_in 0 PULSE 0 3 0 1n 1n 1u 2u
R1 v1_in load 1K

V2 av2_in 0 SIN 0 1 1x
R2 av2_in damped_node 100K
R3 damped_node 0 100K

Rload load gnd 10K

.option nomod nodeck brief numdgt=8

.TRAN 1n 10u

.save all

* Activity checking

* Example 1: blank statement, defaults:
* Check all nodes, no excludes, dv=0.1, start=0, stop=end_of_tran, sort by name, do not produce all_inactive report
* Will produce files acheck.ach0 (active) and acheck.achi0 (inactive)

.acheck

* Example 2: test node pattern as '*', time sort and all_inactive report
* Will produce files acheck.ach1, acheck.achi1 and acheck.achia1 (all inactive)
* Active nodes will be sorted by first activity time 

.acheck * timesort all

* Example 3: test node pattern
* av2_in should be the only active node and no inactive nodes
* Files: acheck.ach2 and acheck.achi2

.acheck *_in exclude="v1*"

* Example 4: test time window 
* Only v1_in should be matched, but reported as inactive holding 3 volts because of time window
* (within duration of the pulse, high value)
* Files: acheck.ach3 and acheck.achi3

.acheck v1* start=2.1u stop=2.9u

* Example 5: test dv threshold
* Matched nodes will be av2_in and damped_node, but damped_node will be reported as inactive since
* dv=0.6 is above the damped sine of 0.5 amplitude
* Files: acheck.ach4 and acheck.achi4

.acheck *a* exclude = "load" dv = 0.6

* Test multiple runs
* .temp will repeat tran and all achecks above
* New files should be created and not overwritten
* In this test setting, files are effectively duplicated
* Title should correctly reflected in .ach* files
.temp 20 80


.control
set unixcom=true
run alters batchprint
'cat acheck.a* > acheck.txt'
.endc

.END

											

											[an error occurred while processing this directive]