20nm Undoped Channel, Ultra-Thin Body and Buried Oxide Fully Depleted SOI NMOSFET in 3D

soiex11.in : 20nm Undoped Channel, Ultra-Thin Body and Buried Oxide Fully Depleted SOI NMOSFET in 3D

Requires: Victory Process / Victory Mesh / Victory Device
Minimum Versions: Victory Process 7.30.4.R / Victory Mesh 1.4.6.R / Victory Device 1.14.1.R

Fully depleted SOI (FDSOI) employing a very thin silicon body on an ultra-thin buried oxide has been considered a potential candidate for aggressive CMOS scaling. Accurate modeling of this kind of FDSOI device necessitates a careful selection of physical models. In this example, 3D device modeling and simulation with Victory Device is demonstrated of a 20nm undoped channel, ultra-thin body and buried oxide FDSOI NMOSFET that is created and meshed using a conformal mesh in Victory Mesh.

Featuring a gate length in the sub-100 nm regime, the FDSOI design is subject to non-local effects such as velocity overshoot. In this respect, the energy balance transport model is favored over the conventional drift-diffusion model. The energy balance model is applicable to electrons by specifying the HCTE.EL parameter in the MODELS statement. For energy balance simulations, it is practical to use the carrier temperature in place of the electric field as the driving force for the field dependent mobility model ( FLDMOB ). The parameter EVSATMOD=0 in the MODELS statement sets the driving force for the high-field saturation model to be electron temperature.

In the ultra-thin channel of the 20nm FDSOI NMOSFET, the significance of quantum confinement of electrons becomes conspicuous. The Bohm quantum potential model allows the quantum confinement effects on electron transport to be included in the simulation by means of the BQP.N parameter of the MODELS statement. The principal quantization direction for Bohm quantum potential can be set to x, y, or z using the BQP.QDIR parameter in the MODELS statement. For the 20nm FDSOI NMOSFET, the direction of quantization is in the Z direction, i.e., BQP.QDIR=Z .

Self-heating effects are common in FDSOI structures due to the low thermal conductivity of the buried oxide. Lattice heating is incorporated in Victory Device through self-consistent solutions of the lattice heat flow equation. The LAT.TEMP flag must be set in the MODELS statement to activate these effects.

The non-local, quantum confinement, and self-heating effects are illustrated by comparing the I-V characteristics of the 20nm FDSOI NMOSFET simulated using the drift-diffusion model with those simulated using the energy balance transport model alone and in combination with the quantum transport and lattice heating models, respectively.

To load and run this example, select the Load button in DeckBuild > Examples. This will copy the input file and any support files to your current working directory. Select the Run button in DeckBuild to execute the example.

Additional Info:

Input Files

Input Deck

											# (c) Silvaco Inc., 2019

go victoryprocess

init layout=soiex11.lay material=silicon depth=0.06 gasheight=2 \
     resolution=0.0015 meshdepth=2

line x location=0.01 spacing=0.002
line x location=0.03 spacing=0.002
line x location=0.05 spacing=0.001
line x location=0.07 spacing=0.001
line x location=0.09 spacing=0.002
line x location=0.11 spacing=0.002

line y location=0    spacing=0.001
line y location=0.02 spacing=0.005
line y location=0.04 spacing=0.001

line z location=-0.037 spacing=0.001
line z location=-0.027 spacing=0.005
line z location=-0.017 spacing=0.001
line z location=-0.015 spacing=0.00025
line z location=-0.01  spacing=0.001
line z location=0      spacing=0.002
line z location=0.02   spacing=0.005
line z location=0.04   spacing=0.001

# SOI Waffer
deposit material=oxide       thick=0.01 max
deposit material=silicon     thick=0.005 max

# Trench
etch dry thick=0.052 mask=TRENCH reverse angle=86 deltacd=-0.003
etch wet thick=0.003 mask=TRENCH reverse deltacd=-0.003
deposit material=oxynitride thick=0 max

# Gate Stack
deposit material=oxide       thick=0.002 max
deposit material=polysilicon thick=0.02 max

# Gate
etch material=polysilicon thick=0.021 mask=GATE max
etch material=oxide thick=0.003 dry

# Spacer
deposit material=nitride thick=0 max
etch material=nitride dry angle=82 thick=0.022 mask=GATE 
deposit material=nitride thick=0.002 conformal curved
etch material=nitride dry thickness=0.0023

doping arsenic=1e15 silicon
mask mask=ACTIVE reverse
implant arsenic energy=1 dose=1e13 tilt=7 rotation=27
strip resist

deposit material=aluminum thick=0.002 min
etch material=aluminum dry thick=0.003 mask=SD

electrodes mask=GATE material=polysilicon
electrodes mask=SD   material=aluminum
electrodes substrate

save name=soiex11_vp


go victorymesh

load in=soiex11_vp

remesh conformal

save out=soiex11_0.str


# Drift-Diffusion
go victorydevice 

mesh infile=soiex11_0.str

interf qf=3e10 z.max=-0.0125
interf qf=1e11 z.min=-0.0125

contact name=gate workfunc=4.5

models cvt srh auger bgn print 
impact selb

method pam.gmres norm.scaling.local dvmax=1.0 climit=1.0e-4

solve init
solve previous

solve vdrain=0.01
solve vdrain=0.05
solve vdrain=0.10

log outfile=soiex11_1_1.log
solve vgate=0.0 vstep=0.05 vfinal=1 name=gate
log off

solve vstep=-0.025 vfinal=0 name=drain

log outfile=soiex11_1_2.log
solve vdrain=0.001
solve vdrain=0.01
solve vdrain=0.05
solve vstep=0.05 vfinal=1 name=drain  
log off


# Energy Balance
go victorydevice 

mesh infile=soiex11_0.str 

interf qf=3e10 z.max=-0.0125
interf qf=1e11 z.min=-0.0125

contact name=gate workfunc=4.5

models cvt srh auger bgn hcte.el evsatmod=0 print
impact selb

method pam.gmres block meinr norm.scaling.local dvmax=1.0 climit=1.0e-4 

solve init 
solve previous

solve vdrain=0.01
solve vdrain=0.05
solve vdrain=0.10

log outfile=soiex11_2_1.log
solve vgate=0.0 vstep=0.05 vfinal=1 name=gate
log off

solve vstep=-0.025 vfinal=0 name=drain

log outfile=soiex11_2_2.log
solve vdrain=0.001
solve vdrain=0.01
solve vdrain=0.05
solve vstep=0.05 vfinal=1 name=drain  
log off


# Energy Balance and Bohm Quantum Potential
go victorydevice 

mesh infile=soiex11_0.str 

interf qf=3e10 z.max=-0.0125
interf qf=1e11 z.min=-0.0125

contact name=gate workfunc=4.5

models cvt srh auger bgn hcte.el evsatmod=0 print 
models bqp.n bqp.qdir=z 
impact selb

method pam.gmres block meinr norm.scaling.local dvmax=1.0 climit=1.0e-4 

solve init bqp.sc
solve previous

solve vdrain=0.01
solve vdrain=0.05
solve vdrain=0.10

log outfile=soiex11_3_1.log
solve vgate=0.0 vstep=0.05 vfinal=1 name=gate
log off

solve vstep=-0.025 vfinal=0 name=drain

log outfile=soiex11_3_2.log
solve vdrain=0.0 vstep=0.0025 vfinal=0.01 name=drain
solve vstep=0.01 vfinal=0.05 name=drain
solve vstep=0.05 vfinal=1 name=drain
log off


# Energy Balance, Bohm Quantum Potential and Lattice Heating
go victorydevice 

mesh infile=soiex11_0.str 

interf qf=3e10 z.max=-0.0125
interf qf=1e11 z.min=-0.0125

contact name=gate workfunc=4.5

models cvt srh auger bgn hcte.el evsatmod=0 print 
models bqp.n bqp.qdir=z 
models lat.temp
impact selb

thermcontact name=substrate ext.temp=300 alpha=1000

method pam.gmres block meinr norm.scaling.local dvmax=1.0 climit=1.0e-4 

solve init bqp.sc
solve previous

solve vdrain=0.01
solve vdrain=0.05
solve vdrain=0.10

log outfile=soiex11_4_1.log
solve vgate=0.0 vstep=0.05 vfinal=1 name=gate
log off

solve vstep=-0.025 vfinal=0 name=drain

log outfile=soiex11_4_2.log
solve vdrain=0.0 vstep=0.0025 vfinal=0.01 name=drain
solve vstep=0.01 vfinal=0.05 name=drain
solve vstep=0.05 vfinal=1 name=drain
log off

tonyplot3d soiex11_0.str -set soiex11_1.set
tonyplot soiex11_1_1.log -overlay soiex11_2_1.log soiex11_3_1.log soiex11_4_1.log -set soiex11_2.set
tonyplot soiex11_1_2.log -overlay soiex11_2_2.log soiex11_3_2.log soiex11_4_2.log -set soiex11_3.set

quit

Output Results

These examples are for reference only. Every software package contains a full set of examples suitable for that version and are installed with the software. If you see examples here that are not in your installation you should consider updating to a later version of the software.