powerex25.in : Silicon Carbide (SiC) Hybrid Junction Termination Extension (HJTE)
Requires: Victory Process, Victory Mesh, Victory Device/Atlas
Minimum Versions: Victory Process 7.76.1.R, Victory Mesh 1.9.0.R, Victory Device 1.20.0.R or Atlas 5.34.0.R
This example demonstrates a novel edge termination technique for SiC devices known as Hybrid Junction Termination Extension (HJTE).
The input deck provided with this example can be run by either Victory Device or Atlas simulator, by changing the solver name in the command go victorydevice into go atlas. It shows that both device simulator frameworks can be fully compatible in terms of input commands, producing comparable results, and allowing easy transition between Atlas and Victory Device.
The example is inspired from the following publication (with experimental data): A Near Ideal Edge Termination Technique for 4500V 4H-SiC Devices: The Hybrid Junction Termination Extension, Woongje Sung, Member, IEEE, and B. J. Baliga, Life Fellow, IEEE.
Hybrid JTE combines MFZ and RA JTE structures in a single edge termination device allowing near ideal breakdown voltage over a wide range of JTE doses. The device presented in this example shows breakdown at 5100V.
You can view internal physical variables inside the devices, such as electric field, impact generation rates, current density distribution, etc. in Tonyplot. The structure files showing doping profiles, breakdown voltage, etc. are saved and can be visualized in Tonyplot.
The example shows:
1.Process simulation of the SiC edge termination device that includes: a. Layout to drive the Guard rings – spacing and doping profiles are as per the publication. b. Process simulation of complete SiC edge termination structure using Victory Process 2.Remeshing the structure using Delaunay remesh strategy in Victory Mesh. 3.Simulation of Breakdown voltage using Victory Device
Since the device is made using WBG material (SiC), the simulation is run using 128-bit precision (recommended), by setting the option:
go victorydevice simflags="-128"
To optimize simulation runtime, the implant profiles are first created in 1D simulation mode using Monte Carlo implantation model. These 1D profiles are later imported in the main 2D structure. The implantation can be toggled between importing 2D profile and using MC implant in 2D structure directly by uncommenting “implant” statements in the process deck and commenting out the “profile” statement.
To load and run this example, select the Load button in Deckbuild > Examples. This will copy the input file and any support files to your current working directory. Select the Run button in Deckbuild to execute the example.
Input Deck
# (c) Silvaco Inc., 2022
#Following example is inspired from this publication: A Near Ideal Edge Termination Technique for 4500V 4H-SiC Devices: The Hybrid Junction Termination Extension, Woongje Sung, Member, IEEE, and B. J. Baliga, Life Fellow, IEEE
#Monte Carlo implantation can be multi-threaded by increasing the number of cores (-P option) in "simflags" statement.
# To optimize the simulation, the example performs 1D implantation to get desired doping profile for P+ rings and MFZ (p-) rings, then imports these profiles in the final 2D structure.
#1D implant profiles for monte carlo implants of p+ wells and p- float zones
go victoryprocess
Init meshdepth=3 material=sic-4h depth=2 gasheight=3.5 resolution=0.05 sub.ori=<0001> sub.miscut.theta=4 \
dopant=nitrogen dopingvalue=1e17 rot.sub=0 sub.miscut.phi=0
#add screen ox
deposit material=oxide thick=0.0500 max
Line z location=0 spacing=0.001
Line z location=2 spacing=0.1
#Implant statements for p- multi float zones (MFZ)
implant aluminum dose=3e12 energy=110 bca n.ion=100000 rotation=0
implant aluminum dose=5e12 energy=200 bca n.ion=100000 rotation=0
implant aluminum dose=5e12 energy=290 bca n.ion=100000 rotation=0
implant aluminum dose=5e12 energy=400 bca n.ion=100000 rotation=0
export structure=powerex25_0.str
go victoryprocess
Init meshdepth=3 material=sic-4h depth=2 gasheight=3.5 resolution=0.05 \
dopant=nitrogen dopingvalue=1e17
deposit material=oxide thick=0.0500 max
Line z location=0 spacing=0.001
Line z location=2 spacing=0.1
#Implant: P+ rings and p+ main well (Anode)
implant aluminum dose=1.0e14 energy=35 bca n.ion=100000 rotation=0
implant aluminum dose=1.0e14 energy=50 bca n.ion=100000 rotation=0
implant aluminum dose=3.0e14 energy=90 bca n.ion=100000 rotation=0
implant aluminum dose=5.0e14 energy=150 bca n.ion=100000 rotation=0
export structure=powerex25_1.str
#Extract statement routine to extract clean 1D implant profiles.
go internal
extract init infile="powerex25_0.str"
extract name="Al_min1" \
min(curve(depth, impurity="Aluminum" material="4h-sic" mat.occno=1 x.val=0))
extract name="ProfileEnd1" \
x.val from curve(depth, impurity="Aluminum" material="4h-sic") where y.val=$Al_min1
#mfz.dat file will store the 1D Aluminum doping for multi-float zone.
extract name="Al_tot1" \
curve(depth, impurity="Aluminum" material="4h-sic" mat.occno=1 x.val=0, x.min=0 x.max=$ProfileEnd1) \
outfile="powerex25_0_mfz.dat"
extract init infile="powerex25_1.str"
extract name="Al_min2" \
min(curve(depth, impurity="Aluminum" material="4h-sic" mat.occno=1 x.val=0))
extract name="ProfileEnd2" \
x.val from curve(depth, impurity="Aluminum" material="4h-sic") where y.val=$Al_min2
#1_pPlus.dat file will store the 1D Aluminum doping for the P-plus well.
extract name="Al_tot2" \
curve(depth, impurity="Aluminum" material="4h-sic" mat.occno=1 x.val=0, x.min=0 x.max=$ProfileEnd2) \
outfile="powerex25_1_pPlus.dat"
#Visualizing doping profiles for P+ rings and P- Float zones.
tonyplot powerex25_0_mfz.dat -set powerex25_set1.set
tonyplot powerex25_1_pPlus.dat -set powerex25_set2.set
#****************VP structure Build***************
#Single zone JTE with floating field rings = Ring-Assisted JTE
# RA-JTE + multiple-floating zone (MFZ-JTE) = hybrid JTE.
set xtemp=200
set ori=0001
go victoryprocess
init material=sic-4h depth=4 from=0 to=$xtemp at=0.5 \
sub.ori=0001 sub.miscut.phi=4 phosphorus=1e17 gasheight=60 resolution=1 meshdepth=2
set pwidth=4
#mask for P+rings (main ANODE + RA-JTE)
specifymaskpoly mask=pplus p="0,0" p="$pwidth,0" p="$pwidth,1" p="0,1" electrode="anode"
#********Mask for Ring Assisted JTE***********
set sn=3
set w1=3
set si=1
set s1=3
set n=1
set s=$s1+($n-1)*$si
set ws=$pwidth+$s
set wp=$ws+$w1
loop steps=6
specifymaskpoly mask=pplus p="$ws,0" p="$wp,0" p="$wp,1" p="$ws,1" add
set n=$n+1
set s=$s1+($n-1)*$si
set ws=$wp+$s
set wp=$ws+$w1
l.end
save name=ringMask
#**********Mask for P- Single zone + MF zones *****************
set s1=1
set si=1
set sz_gap=0
set sz1=$pwidth+$sz_gap
set sz2=$sz1+90
specifymaskpoly mask=pminus p="$sz1,0" p="$sz2,0" p="$sz2,1" p="$sz1,1"
set zone_tot=90
set n_zones=10
set zone_seg=$zone_tot/$n_zones
set w1=7
set s0=2
set alpha=1.07
set w=$w1
set x1=$sz2+$s0
set x2=$x1+$w
set n=1
loop steps=$n_zones
specifymaskpoly mask=pminus p="$x1,0" p="$x2,0" p="$x2,1" p="$x1,1" add
set n=$n+1
set s=$zone_seg-$w
set x1=$x2+$s
set w=$w1/(pow($alpha,($n-1)))
set x2=$x1+$w
l.end
save name=powerex25_layout
line x loc=0 spac=0.5
line x loc=$xtemp spac=0.5
line z loc=-2 spac=1
line z loc=0 spac=1
line z loc=-30 spac=5
line z loc=-35 spac=2
line z loc=-37 spac=0.03
line z loc=-38.5 spac=0.25
line z loc=-39 spac=0.02
line z loc=-40 spac=0.01
#can do both, epitaxy or deposit. Deposit is a faster simulation step.
#epitaxy material=sic-4h thickness=40 time=28 temp=1000 C.Phos=2e15
deposit material=sic-4h thickness=40 c.phos=2e15 sub.ori="0001" sub.miscut.phi=4 max
#export structure=epi.str
deposit material=oxide thick=0.05 max
#Floating zone implant
mask "pminus" reverse thick=2
#Profile statement used to input the 1D profile created above.
#You can use MC implant instead by uncommenting the implant statements and commenting profile statement. Profile is used for optimizing runtime.
Profile infile="powerex25_0_mfz.dat" aluminum lstddev=0.25
# implant aluminum dose=3e12 energy=110 bca n.ion=10000000 rotation=0
# implant aluminum dose=5e12 energy=200 bca n.ion=10000000 rotation=0
# implant aluminum dose=5e12 energy=290 bca n.ion=10000000 rotation=0
# implant aluminum dose=5e12 energy=400 bca n.ion=10000000 rotation=0
export structure=powerex25_02.str
strip barrier
#P+ well implants + Ring implants
mask pplus reverse thick=2
Profile infile="powerex25_1_pPlus.dat" aluminum lstddev=0.3
# implant aluminum dose=1.0e14 energy=35 bca n.ion=10000000 rotation=0
# implant aluminum dose=1.0e14 energy=50 bca n.ion=10000000 rotation=0
# implant aluminum dose=3.0e14 energy=90 bca n.ion=10000000 rotation=0
# implant aluminum dose=5.0e14 energy=150 bca n.ion=10000000 rotation=0
export structure=powerex25_03.str
strip barrier
deposit material=carbon thickness=2 max
#export structure=RA_implant2.str
method material=SiC-4H activation.empirical model=fermi
material material=4h-sic \
dif.parameter = "streamfermiwithoutfield/Al_A/D" \
dif.parametervalue="0.0"
#75% activation. Change dif.parameterValue to change activation%.
material material=4h-sic \
dif.param="activation/Al/cact" dif.parameterValue="2.8e17" dif.parameterUnit="1/cm3"
DIFFUSE TIME=10 minutes TEMPERATURE=1650
#export structure = annealed.str
etch material=carbon dry
etch material=oxide dry
#export structure = bare.str
deposit material=oxide thickness=1 max
etch material=oxide left.to.x=4 dry thickness=1
#export structure=contactHole.str
deposit material=nickel conformal thickness=1
etch material=nickel right.to.x=4.5 thickness=1 dry
#export structure=nickel_cont.str
electrode mask=pplus material=nickel
electrode name=cathode substrate
export structure = powerex25_04.str
save name=powerex25_04_sv
#**********************Victory Mesh: Remeshing structure****************
go victorymesh
load in=powerex25_04_sv
remesh delaunay
refine max.size=0.75 regions="material:nickel" grading="quadratic"
refine max.size=0.75 regions="material:SiO2" grading="quadratic"
refine max.size=2 regions="material:4h-sic" grading="quadratic"
refine max.junction.size=0.1 max.junction.distance=1 max.junction.distance.size=0.5
refine impurity="donor" max.impurity.factor=1 min.impurity.size=0.4
refine max.interface.size=0.200 interface.regions="material:oxide, material:4h-sic" grading="exponential"
refine max.interface.size=0.2200 interface.regions="material:nickel, material:4h-sic" grading="exponential"
save out=powerex25_05_sv
tonyplot powerex25_05_sv.str -set powerex25_set3.set
#*****************************Victory Device: BV Device sim************
go victoryd simflags="-128"
mesh infile=powerex25_05_sv.str cylindrical
contact name=anode
contact name=cathode
save outf=powerex25_06.str
material material=4H-SiC taun0=5e-9 taup0=1e-10 ni.min=5e01
models srh incomplete
impact e.side selb BETAN=1 BETAP=1 AN1=4.0e4 AN2=4.0e4 \
AP1=1.63e7 AP2=1.63e7 BN1=1.67E7 BN2=1.67E7 BP1=1.67E7 BP2=1.67E7
method climit=1e-4 maxtraps=10 itlimit=30 \
ir.tol=1.e-30 ix.tol=1.e-30
solve init
solve prev
save outf=powerex25_07.str
##BV simulation###
solve vanode=0
log outf=powerex25_01.log
solve vcathode=0 vstep=0.1 vfinal=2.5 name=cathode
solve vstep=0.5 vfinal=20 name=cathode
solve vstep=5 vfinal=60 name=cathode
solve vstep=5 vfinal=200 name=cathode
solve vstep=5 vfinal=500 name=cathode
solve vstep=5 vfinal=1000 name=cathode
solve vstep=5 vfinal=1500 name=cathode
solve vstep=10 vfinal=2000 name=cathode
solve vstep=5 vfinal=3000 name=cathode \
compliance=5e-10 cname=cathode
solve vstep=5 vfinal=4000 name=cathode \
compliance=5e-10 cname=cathode
solve vstep=2 vfinal=5000 name=cathode \
compliance=1e-10 cname=cathode
save outf=powerex25_08.str
contact name=cathode current
solve
solve imult ifinal=1e-5 istep=1.2 name=cathode
log off
save outf=powerex25_09.str
tonyplot powerex25_01.log -set powerex25_set4.set
tonyplot powerex25_09.str -set powerex25_set5.set
tonyplot powerex25_09.str -set powerex25_set6.set
quit
