powerex20.in : 3D Vertical LOCOS power MOSFET
Requires Victory Process - Victory Device
Minimum Versions: Victory Process 7.76.1.R, Victory Mesh 1.9.0.R, Victory Device 1.20.0.R
This example is taken from the Silvaco Simulation Standard Article: "Vertical LOCOS Power Devices in Victory Process: From 3D Process and Electrical Optimisation to High Speed, Full Chip Process Emulation, Volume 25, Number 2, April - May - June 2015"
The example creates a simplified process flow in Victory Process for a curved corner vertical LOCOS MOS power device, the structure is then exported and passed into Victory Device for electrical simulation.
The simulation is initialised with a heavily doped N+ layer, this forms the N+ Drain. Once the volume mesh is defined, a thick N-type layer is deposited with a doping of 8E15cm3 followed by a P-type layer of 1E17cm3 which form the N-drift and P-base (source) respectively.
SPECIFYMASKPOLY is then used to define the masks for etching the trench. Two masks are defined to create the trench outline, they are then merged using a Boolean OR operation on them.
Thin oxide and nitride layers are then deposited, the former for the thin gate oxide, the latter to stop oxide growth in subsequent thermal steps.
As a short cut, the single mask set defined previously is used to etch away unnecessary parts of these layers and form the deep trench. The DELTACD parameter is used to shift the dimensions of the mask layer.
Once the thick oxide is grown, polysilicon is used to fill the trench and defined as an electrode.
Finally the device is exported using an unstructured delaunay mesh. The base mesh size is set at 0.2um. mesh refinement is then undertaken on distance to interface with polysilicon to provide drift region refinement along the edge of the thick oxide. Refinement is also undertaken on the P/N junction. Finally a refinement box is defined over the N-Drift/N+ Drain transition.
The exported structure is then passed to Victory Device, a bias is applied to the device and ramped up. Complience is set such that the simulation stops when breakdown is achieved. The EXTRACT statement is used to print out the value of breakdown voltage.
To load and run this example, select the Load button in DeckBuild > Examples. This will copy the input file and any support files to your current working directory. Select the Run button in DeckBuild to execute the example.
Input Deck
# (c) Silvaco Inc., 2022
go victoryprocess
Init material=silicon depth=3 gasHeight=10 orientation=100 sub.rot=45 \
resolution="0.1 0.1 0.12" meshDepth=2 from="-0.8,-0.8" to="1.35,1.35" c.phosphorus=1e+19
Line x location=-0.8 spacing=0.3
Line x location=0.4 spacing=0.03
Line x location=1.35 spacing=0.2
Line y location=-0.8 spacing=0.3
Line y location=0.4 spacing=0.03
Line y location=1.35 spacing=0.2
Line z location=-10 spac=0.1
Line z location=-8.8 spac=0.2
Line z location=-8 spac=0.025
Line z location=-6.8 spac=0.2
Line z location=-3 spac=1
Line z location=0 spac=0.1
Line z location=3 spac=1
#n-type Drift layer
Deposit material=silicon Thickness=8 c.phosphorus=8e+15 conformal
#p-type Base layer
Deposit material=silicon Thickness=0.8 c.BORON=1e17 conformal
SPECIFYMASKPOLY MASK=Rec_1 P1="-1, 0.55" P2="0, 0.55" P3="0, 0" P4="0.55,0" P5="0.55, -1" P6="-1, -1"
SPECIFYMASKPOLY MASK=Circ_1 CIRCLE NPOINTS=100 CENTER="0,0" RADIUS=0.55 FROMANGLE=0 TOANGLE=90
SPECIFYMASKPOLY newmask=J1 mask1=Rec_1 OR mask2=Circ_1
etch Material=silicon thickness=1.8 mask=J1 reverse max
etch material=silicon thick=5.5 mask=J1 reverse max deltacd=-0.06
Deposit material=Oxide Thickness=0.02 mask=J1 reverse deltacd=-0.06 conformal
Deposit material=nitride Thickness=0.04 mask=J1 reverse deltacd=-0.06 conformal
Diffuse Temperature=1050 wet time=33.5 pileupmode=off
strip material=nitride
etch material=oxide above=-8.8
deposit material=poly thick=0.1 max
electrodes name=source z=-8 x=0 y=0
save name=powerex20_vp
###############################################################################
go victorymesh
load in=powerex20_vp
remesh delaunay
refine max.size=0.5
refine max.interface.size=0.05 grading="linear"
refine max.junction.size=0.04 grading="linear"
refine regions="*" max.distance=0.01
save out=powerex20_vm2.str
###############################################################################
go victorydevice
mesh inf=powerex20_vm2.str
electrode name=substrate z.min=3 z.max=3
models conmob fldmob auger fermi bgn consrh print
impact selb
#method pas maxtraps=4 climit=1e-4
method pam.gmres maxtraps=4 climit=1e-4
solve init
log outf=powerex20_0.log
solve name=substrate vsubstrate=0 vfinal=0.1 vstep=0.01
solve name=substrate vfinal=1 vstep=0.1
solve name=substrate vfinal=10 vstep=1
solve name=substrate vfinal=94 vstep=2
solve name=substrate vfinal=105 vstep=0.5 compliance=7e-12 cname=substrate
save outf=powerex20_1.str
extract init inf="powerex20_0.log"
extract name="BV" max(v."substrate")
tonyplot powerex20_0.log -set powerex20_0.set
tonyplot3d powerex20_1.str -set powerex20_1.set
quit
