powerex15.in : SEU Induced Gate Rupture (SEGR) in a Power MOSFET
Requires: SSuprem 4/S-Pisces
Minimum Versions: Athena 5.22.3.R, Atlas 5.34.0.R
This examples demonstrates how an SEU strike in a power MOSFET can create a high transitory gate field sufficient to rupture the gate oxide. Experimnets have shown that a transitory breakdown field across the gate oxide that only lasts for pico-second time scales, is sufficient to rupture the gate causing permanant damage to the device.
A gate rupture event is dependent on both the device bias and the LET of the SEU strike. The bias that creates the most sensitive conditions for a gate rupture event occurs when the field across the gate oxide from the gate bias is in the same direction as the additional field from the induced charges from the SEU event. When this condition occurs, the existing field across the device from the gate bias is re-enforced by the additional field created by the SEU induced charge track, thus minimizing the LET required from the SEU strike to cause a gate rupture event.
The example creates a power MOSFET structure using the Athena process simulator. Circular symmetry is then used for the device simulations, where the center of the cylindrical device is at X=0 (the left hand side of the structure).
An SEU strike with an LET of 37.2 (corresponding to a Bromine Ion), is simulated, with the strike occuring at the center of the device (X=0). At the time of the SEU strike, a bias of -13.9 volts is applied to the gate and 30 volts on the drain. This bias condition creates a near critical condition close to that required for a gate rupture event to occur.
The gate oxide field was probed near the strike, such that gate oxide field versus time could be plotted before, during and after the SEU strike. After the SEU strike occurs, this critical reversed bias condition results in a peak gate oxide field that increases by over 3 times the field from just the DC bias condition alone.
The evolution of the hole concentration distribution was also monitored at 5, 50 and 150 pico seconds after the strike. The drain current was simulated over a longer time span. Just for completeness sake the breakdown voltage and unsaturated threshold voltage (for Vd=0.1 volts) were also simulated.
To load and run this example, select the Load button in DeckBuild > Examples. This will copy the input file and any support files to your current working directory. Select the Run button in DeckBuild to execute the example.
Input Deck
# (c) Silvaco Inc., 2022
# Create the Power MOSFET using Process Simulation
go athena
line x location=0 spacing=0.02
line x location=1.3 spacing=0.5
line x location=2.5 spacing=0.1
line x location=3.5 spacing=0.1
line x location=4.5 spacing=0.5
line x location=5.5 spacing=0.1
line x location=6 spacing=0.1
line x location=8 spacing=0.5
line y location=7.5 spacing=0.2
line y location=8.5 spacing=0.3
init silicon c.phosphor=1.0e20 orientation=100 two.d
method full.cpl
epitaxy time=3 temp=1000 thickness=3 divisions=10 dy=0.20 ydy=3 \
c.phosphor=5.0e15
epitaxy time=3 temp=1000 thickness=3 divisions=10 dy=0.20 ydy=0 \
c.phosphor=2.0e15
epitaxy time=1.5 temp=1000 thickness=1.5 divisions=15 dy=0.01 ydy=0 \
c.phosphor=1.0e16
# Gate Formation
deposit oxide thick=0.05 divisions=5
deposit polysilicon thick=0.6 divisions=6
deposit photoresist thick=1 division=10
etch photoresist right p1.x=3.5
etch polysilicon dry thickness=0.8
# P-Body Formation
implant boron dose=1e13 energy=180 tilt=30 rotation=180 bca n.ion=200000
implant boron dose=1e13 energy=300 tilt=0 rotation=0 bca n.ion=200000
etch photoresist all
# P-Plus Body Contact Formation
deposit photoresist thick=1 division=10
etch photoresist right p1.x=5.5
implant boron dose=5e14 energy=30 tilt=45 rotation=0 bca n.ion=200000
etch photoresist all
method full.cpl cluster.dam
# N-Plus Source Contact Formation
deposit photoresist thick=1 division=10
etch photoresist left p1.x=6
implant arsenic dose=5e14 energy=120 tilt=7 rotation=27 bca n.ion=200000
implant arsenic dose=5e14 energy=120 tilt=7 rotation=207 bca n.ion=200000
etch photoresist all
# Deposit Passivation and Anneal
deposit nitride thickness=1 divisions=10
diffus time=30 temp=1050 nitro
etch nitride right p1.x=5.5
etch oxide right p1.x=5.5
# Make Source Contact
deposit aluminum thick=0.5 divisions=5
electrode name=source x=6
electrode name=gate x=2.5 y=-0.4
electrode name=drain backside
struct outfile=powerex15_0.str
tonyplot powerex15_0.str -set powerex15_0.set
# Single Event Upset Simulation
go atlas
mesh infile=powerex15_0.str cylindrical
set let=37.2
set density=$let*0.011
models consrh cvt auger
contact name=gate n.poly
singleeventupset entrypoint="0,0,0" exitpoint="0,8.5,0" radialgauss \
b.density=$density pcunits radius=0.07 t0=1e-14 tc=1e-15
probe name=Strike_Field field dir=270 x=0.02 y=-0.02
probe name=Source_Field field dir=270 x=3.4 y=-0.02
method climit=1e-4
# Set Up DC Bias Condition
solve init
solve previous
solve vgate=-0.1
solve vgate=-0.4 vstep=-0.5 vfinal=-13.9 name=gate
solve vdrain=0.1
solve vdrain=0.5 vstep=0.5 vfinal=30 name=drain
# Start SEU Transient Simulation
log outfile=powerex15_0.log
solve tfinal=1e-14 dt=1e-16
save outfile=powerex15_1.str
solve tfinal=5e-12 dt=1e-16
save outfile=powerex15_2.str
solve tfinal=50e-12 dt=1e-15
save outfile=powerex15_3.str
solve tfinal=150e-12 dt=1e-14
save outfile=powerex15_4.str
tonyplot powerex15_0.log -set powerex15_1.set
tonyplot powerex15_1.str powerex15_2.str powerex15_3.str powerex15_4.str -set powerex15_2.set
solve tfinal=1e-9 dt=1e-12
tonyplot powerex15_0.log
log off
# DC Breakdown Simulation
go atlas
mesh infile=powerex15_0.str cylindrical
models consrh cvt
impact selb
contact name=gate n.poly
method climit=1e-4 maxtraps=6
solve init
solve previous
log outfile=powerex15_1.log
solve vdrain=0.1
solve vdrain=0.5
solve vdrain=1 vstep=1 vfinal=100 name=drain
contact name=drain current
solve prev
solve name=drain imult istep=2.0 ifinal=3e-2
save outfile=powerex15_5.str
tonyplot powerex15_1.log -set powerex15_3.set
log off
# Unsaturated Threshold Voltage Simulation
go atlas
mesh infile=powerex15_0.str cylindrical
models consrh cvt
contact name=gate n.poly
method climit=1e-4
solve init
solve previous
solve vdrain=0.1
log outfile=powerex15_2.log
solve vgate=0.1 vstep=0.1 vfinal=10 name=gate
tonyplot powerex15_2.log
quit
